PDA

View Full Version : Alguna Buena Persona Me Facilitaria Un Buen Script Para BF1????



JaaviitOxSlayer
25th December 17, 01:11
Plsss

LEX LOST
25th December 17, 06:03
Plsss

instructions inside:

//-------------------------------------------------------------------------------------------
// ANTIRECOIL and RAPIDFIRE (both adjustable on the fly, with ON/OFF and SAVE function)
// AUTOBREATH (Press sensitive) - AUTORUN (Press sensitive) - AUTOSPOT (while aiming)
//-------------------------------------------------------------------------------------------
// Version: 6.1 - Classic
// Platform: Multi
// Controller: Multi
// Game: BF
// Author: LEX LOST
//-------------------------------------------------------------------------------------------
// XBOX INSTRUCTIONS:

// RAPIDFIRE (ON by default - Start value: 13 - GREEN led = ON; RED led = OFF)
// Hold LT and Press Y to Enable or Disable Rapidfire (with rumble notify)
// Hold A and tap UP to increase Rate of Fire (+1 each tap on UP, while holding A)
// Hold A and tap DOWN to decrease Rate of Fire (-1 each tap on DOWN, while holding A)

// ANTIRECOIL (ON by default - Start value: vertical = 30; Horizontal = 0)
// Hold LT and Press A to Enable or Disable Antirecoil (with rumble notify)
// Hold LT and tap UP to increase Antirecoil (+1 each tap on UP, while holding LT)
// Hold LT and tap DOWN to decrease Antirecoil (-1 each tap on DOWN, while holding LT)
// Hold LT and tap RIGHT to compensate to the right (+1 each tap on RIGHT , while holding LT)
// Hold LT and tap LEFT to compensate to the left (+1 each tap on LEFT, while holding LT)

// SAVE new values into the CronusMax eeprom: Hold LT and press MENU (or START, for XBOX360 users)

//-------------------------------------------------------------------------------------------
// PLAYSTATION INSTRUCTIONS:

// RAPIDFIRE (ON by default - Start value: 13 - GREEN led = ON; RED led = OFF)
// Hold L2 and Press TRIANGLE to Enable or Disable Rapidfire (with rumble notify)
// Hold CROSS and tap UP to increase Rate of Fire (+1 each tap on UP, while holding CROSS)
// Hold CROSS and tap DOWN to decrease Rate of Fire (-1 each tap on DOWN, while holding CROSS)

// ANTIRECOIL (ON by default - Start value: vertical = 30; Horizontal = 0)
// Hold L2 and Press CROSS to Enable or Disable Antirecoil (with rumble notify)
// Hold L2 and tap UP to increase Antirecoil (+1 each tap on UP, while holding L2)
// Hold L2 and tap DOWN to decrease Antirecoil (-1 each tap on DOWN, while holding L2)
// Hold L2 and tap RIGHT to compensate to the right(+1 each tap on RIGHT , while holding L2)
// Hold L2 and tap LEFT to compensate to the left (+1 each tap on LEFT, while holding L2)

// Save new values into the CronusMax eeprom: Hold L2 and press OPTIONS (or START, for PS3 users)

//-------------------------------------------------------------------------------------------

//DECLARARATIONS - define

define RFswitch = 17; // XB1_Y - PS4_TRIANGLE
define ARswitch = 19; // XB1_A - PS4_CROSS
//-------------------------------------------------------------------------------------------
define save = 2; // XB1_MENU - PS4_OPTIONS
//-------------------------------------------------------------------------------------------
define AR_Release = 70; // change this value to determine when antirecoil stops working (min: antirecoil value + 10)
define ONLY_WITH_SCOPE = TRUE; // if TRUE Antirecoil IS ON only when scoping - if FALSE, is always ON
//-------------------------------------------------------------------------------------------
define SPOT = 900;//auto-spot modifier
define SPOT_BUTTON = 3;
//-------------------------------------------------------------------------------------------
define UP = 13;
define DOWN = 14;
define LEFT = 15;
define RIGHT = 16;
//-------------------------------------------------------------------------------------------
define Blue = 1;
define Red = 2;
define Green = 3;
define Pink = 4;
define SkyBlue = 5;
define Yellow = 6;
define White = 7;
//-------------------------------------------------------------------------------------------
data(1,
2,0,0,0, //1. Blue
0,2,0,0, //2. Red
0,0,2,0, //3. Lime/Green
0,0,0,2, //4. Fuchsia/Pink
2,0,2,0, //5. SkyBlue
0,2,2,0, //6. Yellow
2,2,2,2 //7. White
);
//-------------------------------------------------------------------------------------------

//VARIABLES - int

int recoil_onoff = TRUE; // if TRUE Antirecoil is ON by default - if FALSE, OFF by default
int rapid_onoff = TRUE; // if TRUE Rapidfire is ON by default - if FALSE, OFF by default
int RATE_OF_FIRE = 13; // Range: 1 to 25 RPS (Round/s)
int ANTI_RECOIL = 30;
int ANTI_RECOIL_H = 0;
int anti_recoil;
int anti_recoil_H;
int Col_ind;
int fire_button;
int scope_button;
int hold_time;
int rest_time;

//-------------------------------------------------------------------------------------------

//INITIALIZATION - init

init{

if(get_console() == PIO_PS3) {
fire_button = 3;
scope_button = 6;
}else {
fire_button = 4;
scope_button = 7;
}

RATE_OF_FIRE = get_pvar(SPVAR_1, 0, 25, 13);
ANTI_RECOIL = get_pvar(SPVAR_2, -100,+100, 30);
ANTI_RECOIL_H = get_pvar(SPVAR_3, -100,+100, 0);
}

//-------------------------------------------------------------------------------------------

//MAIN BLOCK ROUTINES

main {

if (get_val(7)) {combo_run(AutoSpot);}

if(get_val(12)< -95) {set_val(8, 100)} // Autorun

if(get_val(7) > 95) {combo_run(AutoBreath);} // Autobreath
if(get_val(7) < 95) {combo_stop(AutoBreath);}

if(get_val(7) && event_press(ARswitch)) {
combo_run (vibrate);
recoil_onoff=!recoil_onoff;
}

if(get_val(7) && event_press(RFswitch)) {
combo_run (vibrate);
rapid_onoff=!rapid_onoff;
}

if(rapid_onoff) colourled(Green);
else colourled(Red);

if(rapid_onoff) { if(get_val(4)) {
combo_run (RAPID_FIRE);
}
}
hold_time = 500 / RATE_OF_FIRE;
rest_time = hold_time - 20;
if(rest_time < 0) rest_time = 0;

if(get_val(19)) {
if(event_press(UP)) {
RATE_OF_FIRE = RATE_OF_FIRE+ 1;
}
if(event_press(DOWN)) {
RATE_OF_FIRE = RATE_OF_FIRE- 1;
}
set_val(UP,0); set_val(DOWN,0);
}

if(get_val(scope_button) && event_press(save)){
combo_run(vibrate);
set_pvar(SPVAR_1, RATE_OF_FIRE);
set_pvar(SPVAR_2, ANTI_RECOIL);
set_pvar(SPVAR_3, ANTI_RECOIL_H);
set_val(save, 0);
}
if(get_val(7)){
if(event_press(UP)){
ANTI_RECOIL = ANTI_RECOIL+ 1;
}
if(event_press(DOWN)) {
ANTI_RECOIL = ANTI_RECOIL- 1;
}
set_val(UP,0); set_val(DOWN,0);

if(event_press(LEFT)){
ANTI_RECOIL_H = ANTI_RECOIL_H+ 1;
}
if(event_press(RIGHT)) {
ANTI_RECOIL_H = ANTI_RECOIL_H- 1;
}
set_val(LEFT,0); set_val(RIGHT,0);

}
if(!ONLY_WITH_SCOPE || get_val(scope_button) && get_val(fire_button )) {
combo_run(AntiRecoil);
}

if( abs(get_val(10)) > AR_Release || abs(get_val(9)) > AR_Release) {
combo_stop (AntiRecoil);
}
}
//-------------------------------------------------------------------------------------------

//COMBO BLOCKS

combo AutoBreath {
wait(200);
set_val(8, 100);
wait(4000);
}

combo vibrate {
set_rumble(RUMBLE_A, 100);
wait(300);
reset_rumble();
}
//Autospot
combo AutoSpot {//begin
set_val(SPOT_BUTTON, 100);
wait(50);
set_val(SPOT_BUTTON, 0);
wait(SPOT);
}
combo RAPID_FIRE {
set_val(fire_button, 100);
wait(hold_time);
set_val(fire_button, 0);
wait(rest_time);
set_val(fire_button, 0);
}

combo AntiRecoil { // This combo must be the last one
if(recoil_onoff) {
anti_recoil = get_val(10) + ANTI_RECOIL;
if(anti_recoil > 100) anti_recoil = 100;
set_val(10, anti_recoil);
anti_recoil_H = get_val(9) + ANTI_RECOIL_H;
if(anti_recoil_H > 100) anti_recoil_H = 100;
set_val(9, anti_recoil_H);
}
}
// COLOR LED function
//--------------------------------------------------------------
function colourled(Colour) {
Col_ind=(Colour*4)- 3;
set_led(LED_1,dbyte(Col_ind ));
set_led(LED_2,dbyte(Col_ind+ 1));
set_led(LED_3,dbyte(Col_ind+ 2));
set_led(LED_4,dbyte(Col_ind+ 3));
}// End