Console I/O Functions

The CronusMAX PLUS mainly outputs data to a console, however, it does receive data such as rumble and led states which we can read in GPC scripts.  Below are the GPC commands related to this data
 
Console I/O Functions
 
Function Name
Description
set_val
Overwrites the current value of a controller entry
get_console
Returns the current type of console connected to the output port
output_reconnection
Disconnects and Reconnects the USB connection on the output port
ps4_authtimeout
Returns the PS4 authentication timeout state
get_led
Returns the current state of a specified LED
get_rumble
Returns the current vale of a rumble motor
 
1
set_val
 
set_val overwrites the current value of a controller entry with the value that is specified in its second parameter.  What this means is whatever the output is from the controller for the specified button/axis, the set_val command will overwrite that value with the value you specify.
 
It is mainly used in combos to set buttons in sequence, however, it can also be used in the main or user created function.
 
For example, if you were playing a shooter game and wished to create Hair Triggers.  A combo would not be suitable for such a function as you would want the output constant for however long the triggers are held down.  You could use the set_val command within the main section to achieve that function, like so;
 
main {
 
    if(get_val(XB1_LT)) { // If LT / L2 is pressed
        set_val(XB1_LT, 100); // Set LT / L2 to 100 (Fully Pressed)
    }
    if(get_val(XB1_RT)) { // If RT / R2 is pressed
        set_val(XB1_RT, 100); // Set RT / R2 to 100 (Fully Pressed)
    }
 
}
 

Syntax

 
set_val ( <identifier> );
 

Parameters

 
<identifier> : the identifier of a controller entry
2
get_console
 
get_console returns a value in the form of a int which represents the type of console currently connected to the output port of the CronusMAX PLUS.
 
0 (zero) is returned if no console is connected and a value of 1, 2, 4 or 5 is returned if a console is connected, depending on the type of console connected.
 
To save you from remembering which value relates to which type of controller, 4 constants have been created.  They are;
 
Name
Description
Value
  • PIO_PS3
PlayStation 3
1
  • PIO_XB360
Xbox 360
2
  • PIO_PS4
PlayStation 4
4
  • PIO_XB1
Xbox One
5
 
Example of usage:
 
main {
 
    if(get_console() == PIO_XB1) {
       
        // Do Something
 
    }
 
}
 

Syntax

 
get_console (  );
 

Parameters

 
None
 

Returns

 
A value which represents which type of console is currently connected.
3
output_reconnection
 
output_reconnection forces the CronusMAX PLUS to electronically disconnect the output port from the console and then reconnect again.  This function was mainly used to reset the authentication timeout on the PS4, however, it is redundant now as there is no timeout when using a USB HUB on Firmware 1.20 and above.  It has been left in for legacy CronusMAX Users.
 
Example of usage:
 
main {
 
    if(get_val(XB1_MENU) && event_press(XB1_XBOX)) {  // If MENU / OPTIONS / START is held and XBOX / PS button is pressed...
        output_reconnection();  // Disconnect & Reconnect to console
        set_val(XB1_XBOX, 0); // Zero XBOX / PS button to prevent it interfering with game
    }
 
}
 

Syntax

 
output_reconnection (  );
 

Parameters

 
None
4
ps4_authtimeout
 
ps4_authtimeout returns the authentications timeout status on the PS4 in the form of an int.  As with output_reconnection, this function is redundant since Firmware 1.20 and above as Partial PS4 cross over support is no longer required.  However, the function has not been removed as legacy CronusMAX users and those not using a USB Hub would still require it.
 
The main function of ps4_authtimeout is to enable you to script a warning when the CronusMAX PLUS is close to automatically disconnecting and reconnecting to the console when the authentication times out on a PS4.  This could be achieved using a script from our online library;
 
int authcount;
int NOTIFY = 3; //1 = 30 secs 2 = 1 min 3 = 1 min 30 secs and so on up to 16.
 
main{
    //PS4 Cross Over Gaming Section
    if(get_console() == PIO_PS4  && get_controller() != PIO_PS4){
        authcount = ps4_authtimeout();
        swap(1,27);                     // Swap Back/Select with Touchpad Press
        if(get_val(27) && get_val(5)) { // Press Back/Select and press RS/R3 to press share.
            set_val(27, 0);
            set_val(5, 0);
            set_val(1, 100);
        }       
        if(get_val(27)) {             // Hold Back/Select and Press A/Cross to reset Auth Timeout.
            if(event_press(19)){
                output_reconnection();
            }
            set_val(19, 0);
        }
        if(authcount <= NOTIFY + 1) {
            combo_run(notify);
        }
    }
    //PS4 Cross Over Gaming Section End
}
 
combo notify{
    set_rumble(RUMBLE_A, 100);
    set_rumble(RUMBLE_B, 100);
    wait(150);
    reset_rumble();
    wait(250*authcount);
}
 

Syntax

 
ps4_authtimeout (  );
 

Parameters

 
None
 

Returns

 
The PS4 authentication timeout status.  This is a decedent count down with 1 being the last value returned before an Automatic Reconnection is performed by the CronusMAX PLUS.
5
get_led
 
get_led returns a value in the form of an int which represents the current state of the chosen LED.
 
The LEDs range from 0 ~ 3.  Four constants have been created to make it easier to remember which value is assigned to which LED;
 
Name
Description
Value
  • LED_1
LED 1 / Xbox 360 Quadrant 1
0
  • LED_2
LED 2 / Xbox 360 Quadrant 2
1
  • LED_3
LED 3 / Xbox 360 Quadrant 3
2
  • LED_4
LED 4 / Xbox 360 Quadrant 4
3
 
The return value from this function informs you of the current state of the selected LED.  The function returns a value ranging from 0 ~ 3;
 
Return Value
Description
0
LED Off
1
LED On
2
LED Blinking Fast
3
LED Blinking Slowly
 
Example of usage:
 
main {
 
    if(get_led(LED_2) == 1) { // If LED 2 is On
        // Do Something
    }
 
}
 

Syntax

 
get_led ( <Led_Identifier>  );
 

Parameters

 
<Led_Identifier> : The identifier of an LED
 

Returns

 
An int ranging from 0 ~ 3 which represents the current state
 
Click here for more information on LED states
6
get_rumble
 
get_rumble returns the speed of the chosen rumble motor on the controller in the form of an int.  The value returned can range from 0 ~ 100 which represents the speed in a percentage ( % ).
 
The rumble motors are numbered 0 ~ 3.  To make it easier to remember which motor is which, four constants have been created;
 
Name
Description
Value
  • RUMBLE_A
Strong Rumble Motor (Usually the Left Motor)
0
  • RUMBLE_B
Weak Rumble Motor (Usually the Right Motor)
1
  • RUMBLE_RT
Right Trigger Motor (Xbox One controllers only)
2
  • RUMBLE_LT
Left Trigger Motor (Xbox One controllers only)
3
 
Example of usage:
 
main {
 
    if(get_rumble(RUMBLE_A) > 50) {  // If Rumble Motor A is running greater than 50% speed...
        // Do Something
    }
 
}
 

Syntax

 
get_rumble ( <rumble_identifier> );
 

Parameters

 
<rumble_identifier> : the identifier of a Rumble Motor
 

Returns

 
An int ranging from 0 ~ 100 which represents the current speed of the chosen motor
 
Click here for more information on setting Rumble Motors